Browse Source

add dummy package: bird-babel-rtt-debug-git

master
JerryXiao 4 months ago
parent
commit
32fc40a800
Signed by: Jerry
GPG Key ID: 22618F758B5BE2E5
  1. 48
      bird-babel-rtt-debug-git/PKGBUILD
  2. 24
      bird-babel-rtt-debug-git/bird.service

48
bird-babel-rtt-debug-git/PKGBUILD

@ -0,0 +1,48 @@
_pkgname=bird
pkgname=$_pkgname-babel-rtt-debug-git
pkgver=r3826.4c582913
pkgrel=1
pkgdesc='RIP, OSPF, BGP, MPLS, BFD, Babel routing daemon (with babel-rtt)'
arch=('x86_64')
url='https://github.com/tohojo/bird'
license=('GPL2')
backup=('etc/bird.conf')
makedepends=('git' 'autoconf' 'automake')
depends=('glibc' 'readline' 'ncurses' 'libssh')
conflicts=("$_pkgname")
provides=("$_pkgname")
replaces=('bird6')
options=(!emptydirs debug strip)
source=("${_pkgname}::git+https://github.com/tohojo/bird.git#branch=babel-rtt-01"
'bird.service'
)
sha256sums=('SKIP'
'4aa1e8d41229badd276aa3747f613e7df34761892add2258c63bdb5097dfeb2b')
pkgver() {
cd $_pkgname
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd $_pkgname
autoreconf -ifv
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--localstatedir=/var \
--runstatedir=/run/$_pkgname \
--docdir=/usr/share/doc/$_pkgname
make
}
package () {
cd $_pkgname
make DESTDIR="$pkgdir" install
# systemd
install -D -m 644 "$srcdir/bird.service" "$pkgdir/usr/lib/systemd/system/bird.service"
}
# vim:set ts=2 sw=2 et:

24
bird-babel-rtt-debug-git/bird.service

@ -0,0 +1,24 @@
[Unit]
Description=BIRD routing daemon
After=network.target
[Service]
Type=forking
ExecStart=/usr/bin/bird
ExecReload=/usr/bin/birdc configure
ExecStop=/usr/bin/birdc down
RuntimeDirectory=bird
RuntimeDirectoryMode=0750
DynamicUser=true
User=bird
ProtectSystem=strict
ProtectHome=true
ProtectKernelTunables=true
ProtectControlGroups=true
PrivateTmp=true
PrivateDevices=true
CapabilityBoundingSet=CAP_NET_ADMIN CAP_NET_BIND_SERVICE CAP_NET_RAW
AmbientCapabilities=CAP_NET_ADMIN CAP_NET_BIND_SERVICE CAP_NET_RAW
[Install]
WantedBy=multi-user.target
Loading…
Cancel
Save